sábado, 30 de enero de 2016

BETTER BULL BEAR TREND

Chavales , en este programa de Wild BolsaFrank vamos a ver en su habitat a unos animales característicos de nuestra geografía bursátil , los osos y los toros.
Un integrante de nuestro equipo , Jose Callao (Jose7674) Sistemas de Trading para Prorealtime y Mt4 nos ha dado la idea para este capítulo al reformar un archivo de aquellos míticos documentales que veíamos de niños , el   BULL BEAR TREND

Como resultado, el tio fenómeno , ha sacado un nuevo indicador al que hemos bautizado como Better Bull Bear Trend , ya que , a todas luces , supone una mejora sobre el original.
Una visión distinta de como se desenvuelven estos magníficos animales en su entorno , cuyo aspecto es tal y como veís en este gráfico:


En este indicador , osos y toros van por caminos separados.
La linea Bull (alcista en color verde) siempre vá por encima de cero.
La linea Bear (bajista en color rojo) siempre vá por debajo de cero.
Hay delimitadas dos zonas de fuerza de tendencia :
+ (por encima de 2 ) para los toros y - (por debajo de -2 ) para los osos.
Cuando la linea Bull cruza al alza su nivel + 2 , empieza a tener fuerza una tendencia alcista.
Cuando la linea Bear cruza a la baja su nivel -2 , empieza a cobrar fuerza una tendencia bajista.

¿ Qué pasa cuando ambos cruzan sus lineas de fuerza ? ¿ Quién domina el mercado ?....

¡ Ninguno , cojones ! ¡ es un puto lateral , colega !

Como apoyo adicional , tenemos unas señales de corto o largo ( en estilo histograma).
Cuando aparece un histograma positivo, nos indica que la linea Bull está por encima de su nivel + y la linea Bear está por encima de su nivel -.
Cuando es un histograma negativo el que aparece , nos indica que la linea Bear está por debajo de su nivel - y la linea Bull está por debajo de su nivel +.

Es una confirmación de la tendencia.

Una tercera linea (en color negro), es la linea  TREND, que es una diferencia entre la linea Bull y la linea Bear.
Sus cruces por encima/debajo de cero nos sirven para el seguimiento de la tendencia ,a sí como puntos de giros donde podríamos poner un stop loss ...


Bueno tios , ya no me enrollo más , para todos los seguidores de este espacio , para que flipeís en colores...
el código para la plataforma Prorealtime es :

--------------------------------------------------------------------------------------------
REM BETTER BULL BEAR TREND
//código original publicado en foro Aktienboard
//by Rumpe- Marzo 2008
//modificado por Jose Callao - Enero 2016

REM determinamos la fuerza de la tendencia alcista
BullTrend = (CLOSE - LOWEST[50](LOW)) / AVERAGETRUERANGE[5]

limite= 2 //variable a configurar, normalmente entre 2 y 2.5
limiteneg= -1*2
REM Determinamos la fuerza de la tendencia bajista
BearTrend = (HIGHEST[50](HIGH) - CLOSE) / AVERAGETRUERANGE[5]
Beartrend2= -1*Beartrend

Trend = Bulltrend - BearTrend

largos= 2-beartrend
if largos >0 and trend>2 then
largos1= largos
else
largos1=0
endif

cortos= -1*(2-bulltrend)
if cortos<0 and trend<limiteneg then
cortos1=cortos
else
cortos1=0
endif

RETURN BullTrend  COLOURED  (0,155,0)  AS "Bull", BearTrend2 COLOURED (255,0,0) AS "Bear", Trend  AS "Trend", 0 AS "0", limite as "+", limiteneg as "-", largos1 as "largos", cortos1 as "cortos"

----------------------------------------------------------------------------------------------------
Configurar en estilo histograma cortos y largos.


La tendencia es nuestra amiga y nosotros somos amigos de los animales.

domingo, 24 de enero de 2016

BULL BEAR TREND





Queridos amigos de la fauna bursátil , en el episodio de hoy de el hombre y la bolsa , vamos a hablar de dos animales que pululan por nuestro territorio :
los toros y los osos.


Cuando el toro corre libremente por las dehesas de nuestros mercados , las bolsas se tornan alcistas.
Cuando el oso sale de la osera y pasea por esos montes, es cuando las bolsas se tornan bajistas. 

Es interesante saber en cada momento cúal de estos animales es el que domina las plazas de cotización.
Para ello, nuestro equipo de redacción ha rescatado un documento de un foro alemán , creado por un compañero naturista.
El indicador BULL BEAR TREND.

Consta de tres lineas :
Una de color verde (BULL) que se identifica con los toros
otra de color rojo (BEAR) ,que identifica a los osos
y una tercera de color negro (TREND) que es la diferencia de ambas :


La linea negra (TREND) , nos marca la dirección de la tendencia ,cuando la linea TREND pasa por encima de cero , puede iniciarse una tendencia alcista,cuando pasa por debajo de cero nos indica el inicio de una tendencia bajista.
Los cruces entre la linea verde y la roja ,nos habla del posicionamiento de osos o toros y así mismo nos sirven como puntos de inflexión , posibles giros de la tendencia anterior y zonas donde colocar el stop loss...


Para todos nuestros telespectadores , como novedad , presentamos el código castellanizado, para la plataforma Prorealtime de esta ingeniosa herramienta :

-----------------------------------------------------------------------------------------------
REM BULL BEAR TREND
//código original publicado en foro Aktienboard
//by Rumpe- Marzo 2008

REM determinamos la fuerza de la tendencia alcista
BullTrend = (CLOSE - LOWEST[50](LOW)) / AVERAGETRUERANGE[5]


REM Determinamos la fuerza de la tendencia bajista
BearTrend = (HIGHEST[50](HIGH) - CLOSE) / AVERAGETRUERANGE[5]

Trend = Bulltrend - BearTrend

RETURN BullTrend  COLOURED  (0,155,0)  AS "Bull", BearTrend COLOURED (255,0,0) AS "Bear", Trend  AS "Trend", 0 AS "0"

----------------------------------------------------------------------------------------------


Ni que decir tiene, que hemos sido testigos en estos últimos días del ataque del oso en nuestro mercado y que aún a dia de hoy , a pesar de los rebotes producidos por los toros , siguen dominando la situación, la cual ha sufrido la fiereza de sus zarpazos y han dejado a nuestro indice muy maltrecho.
Seguiremos atentos a la evolución de estos maravillosos animales , claves para nuestras plazas financieras.

sábado, 16 de enero de 2016

PARANOIA

Paranoia , según la real academia de la lengua española  es una perturbación mental fijada en una idea o en un orden de ideas.
También es un indicador de última generación que intenta juntar en un solo indicador el  Macd , el Rsi y el estocástico , todos a la vez.
El nombre viene de que este indicador es una paranoia de Curses , el propietario del blog chartcurses.wordpress.com con un desarrollo de la idea original de mano de Jose Callao  jose7674.blogspot.com.es

Su aspecto visual así como unas pequeñas instrucciones de uso los teneís en estos gráficos que me mandó Jose :




Estamos de enhorabuena mangurrianes , en primicia para Bolsatrilera y todos sus lectores , se me ha cedido el código de este cañero indicador para su divulgación.

En el código original todas los parámetros de las variables se colocaban en el cuadro de variables .Para hacer más sencillo el paso de este código a la plataforma Prorealtime , me he tomado la libertad de incluir los parámetros en el código a excepción de n (detector de divergencias).

Dicen que de bien nacido es ser agradecido , así que desde aquí , demoslé las gracias a Jose y a Curses por cedernos esta herramienta :

-----------------------------------------------------------------------------------------------------

//INDICADOR PARANOIA
//DESARROLLADO POR CURSES Y JOSE 7674
// TWITTER: @cursetes
// chartcurses.wordpress.com


rem partimos del rsi, macd y estocastico
rem dándole mas importancial al macd, menos al rsi y mucho menos al estocastico
rem todas las variable son editables, excepto las proporciones


//PARANOIA RAPIDO
a=(RSI[13](close)-50)/50
valor1=ExponentialAverage[5](close)
valor2=ExponentialAverage[13](close)
valor3=valor1/valor2
valor4=ExponentialAverage[7](valor3)
b=(valor3/valor4-1)*100
c=(Stochastic[6,3](close)-50)/50
paranoiar=(((a*23.6)+(b*61.8)+(c*14.6))/3)/10



//PARANOIA LENTO
a2=((RSI[21](close))-50)/50
valor12=ExponentialAverage[12](close)
valor22=ExponentialAverage[26](close)
valor32=valor12/valor22
valor42=ExponentialAverage[9](valor32)
b2=(valor32/valor42-1)*100
c2=(Stochastic[21,3](close)-50)/50
paranoial=(((a2*23.6)+(b2*61.8)+(c2*14.6))/3)/10

cero=0
superior= 2 //zona de sobrecompra en diario
inferior= -2 //zona de sobreventa en diario


///La variable N es el numero de barras hacia atras que utilizamos para encontrar una divergencia


///Divergencias Paranoiar (RAPIDO)
IF (BarIndex > 10+1+N) THEN


IF (paranoiar[1]>paranoiar AND paranoiar[1]>paranoiar[2]) THEN
extremum2=paranoiar[1]
extremum1=highest[N](paranoiar)


preciomax2=close[1]
preciomax=Highest[N](close)
ENDIF


IF (paranoiar[1]<paranoiar AND paranoiar[1]<paranoiar[2]) THEN
extremum22=paranoiar[1]
extremum11=lowest[N](paranoiar)


preciomin2=close[1]
preciomin=lowest[N](close)
ENDIF


REM aseguramos que el maximo actual es inferior al maximo de las N barras previas
IF(extremum2<extremum1 AND preciomax2>preciomax[1]) THEN
signal = -0.25
ELSE
signal = 0
ENDIF


IF(extremum22>extremum11 AND preciomin2<preciomin[1]) THEN
signal = 0.25
ENDIF


ENDIF


///Divergencia paranoiaL (lento)


IF (BarIndex > 10+1+N) THEN


IF (paranoial[1]>paranoial AND paranoial[1]>paranoial[2]) THEN
extremum4=paranoial[1]
extremum3=highest[N](paranoial)


preciomax4=close[1]
preciomax3=Highest[N](close)
ENDIF


IF (paranoial[1]<paranoial AND paranoial[1]<paranoial[2]) THEN
extremum44=paranoial[1]
extremum33=lowest[N](paranoial)


preciomin4=close[1]
preciomin3=lowest[N](close)
ENDIF


REM aseguramos que el maximo actual es inferior al maximo de las N barras previas
IF(extremum4<extremum3 AND preciomax4>preciomax3[1]) THEN
signal2 = -0.5
ELSE
signal2 = 0
ENDIF


IF(extremum44>extremum33 AND preciomin4<preciomin3[1]) THEN
signal2 = 0.5
ENDIF


ENDIF


RETURN signal2 as "dlento", signal as "drapido", paranoiar as "paranoiar", paranoial as "Paranoial", cero as "0", superior as "2", inferior as "-2"

--------------------------------------------------------------------------------------------------------

En el cuadro de variables :

n = detector de divergencias = 15


Configurar dlento y drapido en estilo histograma añadiendo colores para positivo y negativo.

domingo, 10 de enero de 2016

DE SOPORTE A RESISTENCIA

Un soporte es un nivel donde se frena el retroceso de los precios.
Una resistencia es un nivel donde se frena el avance de los precios.
Este paradigma tiene una propiedad : la reversibilidad.
Un soporte perforado se convierte en resistencia y viceversa.

Trasteando el indicador Ziggy Evolution aparecido en el artículo SOPORTES Y RESISTENCIAS CON ZIGGY ha salido una reforma que puede resultar útil.
El aspecto visual queda de esta manera...


Por sí mismo, podríamos utilizar el indicador soporte/resistencia utilizando las roturas de esos niveles para hacer entradas de bajo riesgo ,tal y como nos propone el análisis técnico ortodoxo.
También , el análisis técnico tradicional nos propone analizar el volumen en estas zonas, como muestra, mirad de nuevo el gráfico de Arcelor con el Volumen climático trilero incorporado...


Si , tenemos una barra de volumen climático de giro justo en zona de soporte.
Es una entrada de bajo riesgo aún a costa de que se dé la vuelta...y eso es lo bueno de esta operativa.


El acceso libre a la información y a la diversidad nos conduce a la libertad , a la igualdad y a la tolerancia.
Es por ello , que sin más dilación , se hace público el código de este indicador que 9 de cada 10 analistas recomiendan.
Para la plataforma Prorealtime , el código es :

---------------------------------------------------------------------------------------------------
REM SOPORTE/RESISTENCIA
//modificación del indicador Ziggy Evolution
// publicado en el foro finanzaonline.com
//programado por Tetsuo, Octubre 2009
//modificado en Enero 2016

once ziggy=0
myatr=AverageTrueRange[14](close)
empieza=(ziggy/1000*n)+myatr

once trend=1

if trend=1 then
if close>close[1] and close>ziggy[1] then
ziggy=close
elsif close>close[1] and close<ziggy[1] then
ziggy=ziggy[1]
elsif close<close[1] and (ziggy-empieza)<close then
ziggy=ziggy[1]
elsif close<close[1] and (ziggy-empieza)>close then
ziggy=close
trend=-1
endif
endif

if trend=-1 then
if close<close[1] and close<ziggy[1] then
ziggy=close
elsif close<close[1] and close>ziggy[1] then
ziggy=ziggy[1]
elsif close>close[1] and (ziggy+empieza)>close then
ziggy=ziggy[1]
elsif close>close[1] and (ziggy+empieza)<close then
ziggy=close
trend=1
endif
endif

if trend=1 and trend[1]=-1 then
soporte=ziggy[1]

elsif trend=-1 and trend[1]=-1 then
soporte=soporte[1]
endif

if trend=-1 and trend[1]=1 then
resistencia=ziggy[1]

elsif trend=1 and trend[1]=1 then
resistencia=resistencia[1]
endif

if resistencia<>resistencia[1] then
res1=resistencia
elsif soporte<>soporte[1] then
sup1=soporte
endif



return  sup1 coloured(0,0,255) as "soporte",  res1 coloured(255,0,0) as "resistencia"

--------------------------------------------------------------------------------------------------------

En el cuadro de variables :

n = número de días = 20

Poner directamente en precio y configurar en estilo puntos.