Robando el índicador a Carlos, decidí incorporarlo al estraperlo pro y modificarlo.
Quería una nueva versión que mantuviera la idea clave central del estraperlo original (basado en los estudios de Jose7674), eliminando las barras chivatas (repintan demasiado), y manteniendo la genialidad de las barras de volumen que incorporó Miguel Leuguim en el estraperlo pro , al mismo tiempo que cambiar el macd estándar por el oscilador macd.
Como soy un aficionadillo en esto de la programación en la plataforma Prorealtime,me he tirado días tratando de dar con un código correcto para tal tarea ...y no lo conseguía.
Lo mejor en estos casos es contactar con alguién que te pueda ayudar, así que contacté con Leuguim,mandándole el esbozo de código y el concepto.
Esta misma mañana ya estaba listo y enviado a mi correo.
El aspecto , así como los elementos que voy a desgranar a continuación quedan tal que así...
Para su comprensión vamos a desglosar sus componentes :
Curva estraperlo : es la curva formada por un macd con combinación 5,13,1
Banda de Bollinguer : una banda de Bollinguer a 60 periodos y desviación estándar 1
Línea señal : una media exponencial a cuyo cruce con la curva estraperlo dá señales de entrada o salida.
Barras de volumen : muy útiles.Cuando aparecen de forma aislada nos indican un volumen climático , lo que en ocasiones es una reversión del precio.Si aparece más de una barra seguida , nos habla de una posible acumulación o distribución.
Oscilador Macd : muy interesante .Una concepción de Calatravo , que modifica un macd 12,26,9 con una media a los máximos y mínimos de un periodo de 50 , consiguiendo zonas de sobrecompra y sobreventa.
Demósle las gracias a Miguel Leuguim por su curro desinteresado.
Para todo el que lo quiera , ¡ totalmente gratis , oiga !, el código para la plataforma Prorealtime es :
------------------------------------------------------------------------------------------------------------------
//ESTRAPERLO REMIX
//Creado por Miguel Ángel Castillo basado en el Estraperlo. Octubre 2015
//Parte de código de Macd Normalisé by hk_lisse
//Parte de código de Macd de Carlos Rozas
//Parte de código de Capital Proporcional Medio by Javier Alfayate
//Revisado por Miguel Leugim (sud_miguel@hotmail.com). Octubre 2015
//Indicador estraperlo
val1=Exponentialaverage[5](close)
val2=ExponentialAverage[13](close)
mmacd=val1/val2-1
se=ExponentialAverage[m](mmacd)
gd2=average[60](mmacd)
sd=1*STD[60](mmacd)
bollsup=gd2+sd
bollinf=gd2-sd
//Oscilador Macd
valor1=ExponentialAverage[12](close)
valor2=ExponentialAverage[26](close)
a=valor1/valor2-1
b=exponentialaverage[50](highest[n](a))
c=exponentialaverage[50](lowest[n](a))
if a>b then
SC=a-b
else
SC=0
endif
if a<c then
SV=a-c
else
SV=0
endif
//Indicador Capital Proporcional Medio
capital = volume * close
volmax = highest[200](capital)
vol = ((capital*100/volmax)*4/5)
volmed = ExponentialAverage[50](vol)
CPM = (vol - volmed)
volumen = capital / (Average[20](capital)[1]) > 2 AND CPM > 0
IF volumen THEN
bvol = 1.2
ELSE
bvol = 0
ENDIF
RETURN SC*100 COLOURED (255,153,0) as "SC",SV*100 COLOURED (0,204,51)as "SV", bvol COLOURED (0,0,200) as "Volumen", 0 as "Cero",mmacd*100 as "LM",se*100 as "S",bollsup*100 as "BSUP",bollinf*100 as "BINF"
---------------------------------------------------------------------------------------------------
En el cuadro de variables :
m = media = 20
n = n = 50
nota: configurar en estilo histograma las nomenclaturas SC , SV y Volumen.
